int PARTICLE_NUM = 1000;
float PARTICLE_RADIOUS = 1.5;
float PARTICLE_MAX_SPEED = 10.0;
float PARTICLE_MAX_ACCELERATION = 1.0;
float PARTICLE_IMPACT_SPEED = 300;
float PARTICLE_SPEED_VARIANT = 0.1;
Particle[] particles;
void setup(){
size(500, 500);
particles = new Particle[PARTICLE_NUM];
for(int i = 0; i < PARTICLE_NUM; i++){
particles[i] = new Particle();
}
}
void draw(){
background(255);
for(Particle particle: particles){
particle.display();
particle.update();
}
}
void mousePressed(){
for(Particle particle: particles){
particle.impact();
}
}
class Particle{
PVector position;
PVector velocity;
Particle(){
position = new PVector(random(width), random(height));
setRandomVelocity();
}
void setRandomVelocity(){
velocity = new PVector(random(2) - 1.0, random(2) - 1.0);
velocity.normalize();
velocity.mult(random(PARTICLE_MAX_SPEED * 2) - PARTICLE_MAX_SPEED);
}
void impact(){
velocity = PVector.random2D();
velocity.normalize();
velocity.mult(PARTICLE_IMPACT_SPEED);
}
void display(){
noStroke();
fill(160);
ellipse(position.x, position.y, PARTICLE_RADIOUS * 2, PARTICLE_RADIOUS * 2);
}
void update(){
PVector mouse = new PVector(mouseX, mouseY);
PVector direction = PVector.sub(mouse, position);
direction.normalize();
PVector acceleration = PVector.mult(direction, PARTICLE_MAX_ACCELERATION);
velocity.add(acceleration);
PVector velocityVariant = new PVector(random(2) - 1.0, random(2) - 1.0);
velocityVariant.normalize();
velocityVariant.mult(PARTICLE_SPEED_VARIANT);
velocity.add(velocityVariant);
velocity.limit(PARTICLE_MAX_SPEED);
position.add(velocity);
}
}